  10 CLS : PRINT "B E R G E R O V E  T A B L I C E": INPUT "Broj ucesnika (3-99): ";m: IF m<>INT m OR m<3 OR m>99 THEN GO TO 10
  20 LET n=2*(m-INT (m/2)): DIM a(n)
  30 INPUT "Kolo broj(1-";(n-1);", 0 ili CR): "; LINE k$: IF k$="" THEN LET k=1: GO TO 60
  40 FOR i=1 TO LEN k$: IF k$(i)<"0" OR k$(i)>"9" THEN GO TO 30
  50 LET k=VAL k$: IF k<1 THEN GO TO 10
  55 IF k>n-1 THEN GO TO 30
  60 LET j=k: IF j/2=INT (j/2) THEN LET y=(n+j)/2: GO TO 80
  70 LET y=(j+1)/2
  80 FOR i=1 TO n-2: LET a(i)=y+i-(n-1)*(y+i>=n): NEXT i
  90 PRINT AT 1,0;"kolo:";j;". ","ukupno kola:";n-1;AT 3,0;
 100 IF m<>n THEN PRINT " " AND y<10;y;" **": GO TO 130
 110 IF y>n/2 THEN PRINT " " AND n<10;n;"-";" " AND y<10;y: GO TO 130
 120 PRINT " " AND y<10;y;"-";" " AND n<10;n
 130 FOR i=1 TO n/2-1: LET f=INT (i/17): PRINT AT 3+i-f*17*(i>16),f*13*(i>16);" " AND a(i)<10;a(i);"-";" " AND a(n-1-i)<10;a(n-i-1): NEXT i
 140 PRINT AT 21,0;"1-preth.    0-sled.    9-br.kola": PAUSE 0: LET a$=INKEY$: IF a$="9" THEN GO TO 30
 150 IF a$="0" THEN PRINT AT 21,12;"0": IF k<n-1 THEN LET k=k+1
 160 IF a$="1" THEN PRINT AT 21,0;"1": IF k>1 THEN LET k=k-1
 170 IF j=k THEN GO TO 140
 180 GO TO 60
